DebugKeybind/build.gradle at dev · Boxadactle/DebugKeybind · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
plugins {
    // see https://fabricmc.net/develop/ for new versions
    id 'fabric-loom' version '1.11-SNAPSHOT' apply false
    // see https://projects.neoforged.net/neoforged/moddevgradle for new versions
    id 'net.neoforged.moddev' version '2.0.115' apply false

    id "me.modmuss50.mod-publish-plugin" version "0.8.4"
    id "com.github.breadmoirai.github-release" version "2.5.2"
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'

    repositories {
        // Fix issue with lwjgl-freetype not being found on macOS / ForgeGradle issue
        //
        // Could not resolve all files for configuration ':_compileJava_1'.
        // Could not find lwjgl-freetype-3.3.3-natives-macos-patch.jar (org.lwjgl:lwjgl-freetype:3.3.3).
        maven {
            url "https://libraries.minecraft.net"
            content {
                includeModule("org.lwjgl", "lwjgl-freetype")
            }
        }
        mavenCentral()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "https://repo.lucko.me/" }
        maven { url "https://jitpack.io" }
        maven { url = "https://maven.terraformersmc.com/releases/" }
        maven { url = "https://maven.boxadactle.dev/releases" }
        maven { url = "https://maven.boxadactle.dev/snapshots" }
    }
}

publishMods {
    changelog = new File(rootProject.rootDir, project.changelog_file).text
    type = STABLE

    def cfOptions = curseforgeOptions {
        accessToken = System.getenv("CURSEFORGE_TOKEN")
        projectId = project.project_id_curseforge
        minecraftVersions.addAll(project.game_versions.split(","))
        changelogType = "markdown"
        javaVersions.add(JavaVersion.current())
    }

    def mrOptions = modrinthOptions {
        accessToken = System.getenv("MODRINTH_TOKEN")
        projectId = project.project_id_modrinth
        minecraftVersions.addAll(project.game_versions.split(","))
    }

    curseforge("curseforgeFabric") {
        from cfOptions
        file project(":fabric")
        modLoaders.addAll("fabric", "quilt")
        requires {
            slug = "fabric-api"
        }
        displayName = "[Fabric ${project.minecraft_version}] v${project.version}"
    }

    curseforge("curseforgeForge") {
        from cfOptions
        file project(":forge")
        modLoaders.add("forge")
        displayName = "[Forge ${project.minecraft_version}] v${project.version}"
    }

    curseforge("curseforgeNeoforge") {
        from cfOptions
        file project(":neoforge")
        modLoaders.add("neoforge")
        displayName = "[Neoforge ${project.minecraft_version}] v${project.version}"
    }

    modrinth("modrinthFabric") {
        from mrOptions
        file project(":fabric")
        modLoaders.addAll("fabric", "quilt")
        requires {
            slug = "fabric-api"
        }
        displayName = "[Fabric ${project.minecraft_version}] v${project.version}"
    }

    modrinth("modrinthForge") {
        from mrOptions
        file project(":forge")
        modLoaders.add("forge")
        displayName = "[Forge ${project.minecraft_version}] v${project.version}"
    }

    modrinth("modrinthNeoforge") {
        from mrOptions
        file project(":neoforge")
        modLoaders.add("neoforge")
        displayName = "[Neoforge ${project.minecraft_version}] v${project.version}"
    }
}

githubRelease {
    owner = "Boxadactle"
    repo = "DebugKeybind"
    tagName = "$project.version"
    targetCommitish = "dev"
    releaseName = "${mod_name} $project.version"
    generateReleaseNotes = true
    body = """${mod_name} $project.version for Minecraft $minecraft_version

${new File(rootProject.rootDir, project.changelog_file).text}
"""
    authorization = "Token ${System.getenv("GITHUB_TOKEN")}"

    var files = []
    for (String platform : project.enabled_platforms.split(',')) {
        files += fileTree("$platform/build/libs") {
            include "*$project.version*"
        }
    }
    releaseAssets = files

//    dryRun = true
}